cmake_minimum_required(VERSION 3.16)
project(twinplay VERSION 0.1.6 LANGUAGES C CXX)
set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_POSITION_INDEPENDENT_CODE ON)
option(TWINPLAY_BUILD_APP "Build the Qt/Lomiri application" ON)
option(TWINPLAY_ENABLE_JIT "Include melonDS ARM64/x86_64 JIT" ON)
include(CTest)
find_package(Threads REQUIRED)
set(BUILD_QT_SDL OFF CACHE BOOL "" FORCE)
set(ENABLE_JIT ${TWINPLAY_ENABLE_JIT} CACHE BOOL "" FORCE)
set(ENABLE_GDBSTUB OFF CACHE BOOL "" FORCE)
set(ENABLE_OGLRENDERER OFF CACHE BOOL "" FORCE)
set(ENABLE_LTO_RELEASE OFF CACHE BOOL "" FORCE)
set(ENABLE_LTO OFF CACHE BOOL "" FORCE)
set(TEAKRA_BUILD_TOOLS OFF CACHE BOOL "" FORCE)
set(TEAKRA_BUILD_UNIT_TESTS OFF CACHE BOOL "" FORCE)
add_subdirectory(vendor/melonDS EXCLUDE_FROM_ALL)
target_compile_definitions(core PRIVATE TWINPLAY_CONFINED=1)
add_library(twinplay-engine STATIC src/CoreHost.cpp src/CoreSession.cpp src/CheatCore.cpp src/DsLanguage.cpp)
target_include_directories(twinplay-engine PUBLIC src)
target_link_libraries(twinplay-engine PUBLIC core Threads::Threads ${CMAKE_DL_LIBS})
if(BUILD_TESTING)
   add_executable(ds-language-test tests/ds-language.cpp)
   target_link_libraries(ds-language-test PRIVATE twinplay-engine)
   add_test(NAME native-ds-firmware-language COMMAND ds-language-test)
   add_executable(core-test tests/core-test.cpp)
   target_link_libraries(core-test PRIVATE twinplay-engine)
   add_test(NAME native-core COMMAND core-test)
   add_executable(cheats-test tests/cheats-core.cpp)
   target_link_libraries(cheats-test PRIVATE twinplay-engine)
   target_compile_definitions(cheats-test PRIVATE TWINPLAY_SOURCE_DIR="${CMAKE_CURRENT_SOURCE_DIR}")
   add_test(NAME native-cheat-engine COMMAND cheats-test)
endif()
if(TWINPLAY_BUILD_APP)
   set(CMAKE_AUTOMOC ON)
   set(CMAKE_AUTORCC ON)
   find_package(Qt5 5.12 REQUIRED COMPONENTS Core Concurrent Gui Qml Quick Multimedia)
   add_library(twinplay-ui STATIC
      src/AppPaths.cpp src/SettingsStore.cpp src/Library.cpp src/CheatManager.cpp src/Emulator.cpp src/DsScreen.cpp)
   target_link_libraries(twinplay-ui PUBLIC twinplay-engine Qt5::Core Qt5::Concurrent Qt5::Gui Qt5::Qml Qt5::Quick Qt5::Multimedia)
   add_executable(twinplay src/main.cpp resources.qrc)
   target_link_libraries(twinplay PRIVATE twinplay-ui)
   if(BUILD_TESTING)
      add_executable(settings-test tests/settings-test.cpp src/AppPaths.cpp src/SettingsStore.cpp)
      target_link_libraries(settings-test PRIVATE Qt5::Core)
      add_test(NAME settings-fresh-process COMMAND settings-test)
   endif()
   set(ARCH "$ENV{ARCH}")
   set(ARCH_TRIPLET "$ENV{ARCH_TRIPLET}")
   set(CLICK_FRAMEWORK "$ENV{CLICK_FRAMEWORK}")
   set(APPARMOR_POLICY "$ENV{APPARMOR_POLICY}")
   if(NOT ARCH)
      set(ARCH amd64)
   endif()
   if(NOT ARCH_TRIPLET)
      set(ARCH_TRIPLET "${CMAKE_LIBRARY_ARCHITECTURE}")
   endif()
   if(NOT CLICK_FRAMEWORK)
      set(CLICK_FRAMEWORK ubuntu-touch-24.04-1.x)
   endif()
   if(NOT APPARMOR_POLICY)
      set(APPARMOR_POLICY 16.04)
   endif()
   configure_file(manifest.json.in manifest.json @ONLY)
   configure_file(twinplay.apparmor.in twinplay.apparmor @ONLY)
   install(TARGETS twinplay RUNTIME DESTINATION lib/${ARCH_TRIPLET}/bin)
   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/manifest.json ${CMAKE_CURRENT_BINARY_DIR}/twinplay.apparmor twinplay.desktop twinplay.contenthub DESTINATION .)
   install(FILES assets/logo.png DESTINATION assets)
   # Install the 55 MB R4 database as a regular read-only Click asset. Avoid
   # embedding it in qrc or copying a second copy into the writable data root.
   install(FILES assets/cheats/usrcheat.dat DESTINATION assets/cheats)
   install(FILES LICENSE README.md THIRD-PARTY.md CHANGELOG.md OPENSTORE-DESCRIPTION.txt DESTINATION share/twinplay)
   install(DIRECTORY licenses/ DESTINATION share/twinplay/licenses)
endif()
