cmake_minimum_required(VERSION 3.16)
project(smsforwarder LANGUAGES CXX)

set(APP_VERSION "0.1.4")
set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_AUTOMOC ON)
set(CMAKE_POSITION_INDEPENDENT_CODE ON)

option(BUILD_APP "Build the Ubuntu Touch application and Click metadata" ON)
option(BUILD_REGRESSION_TESTS "Build native persistence and local TLS SMTP tests" OFF)
find_package(Qt5 REQUIRED COMPONENTS Core Network)
find_package(OpenSSL REQUIRED)

set(APP_SOURCES
   src/SettingsStore.cpp
   src/SettingsStore.h
   src/SmtpClient.cpp
   src/SmtpClient.h
   src/SmsForwarderBackend.cpp
   src/SmsForwarderBackend.h
   src/BackupManager.cpp
   src/BackupManager.h
)

if(BUILD_APP)
   find_package(Qt5 REQUIRED COMPONENTS Gui Qml Quick)
   if(NOT DEFINED ENV{ARCH_TRIPLET})
      message(FATAL_ERROR "ARCH_TRIPLET is not set. Build this project with Clickable.")
   endif()

   set(ARCH "$ENV{ARCH}")
   set(ARCH_TRIPLET "$ENV{ARCH_TRIPLET}")
   set(CLICK_FRAMEWORK "$ENV{CLICK_FRAMEWORK}")
   set(APPARMOR_POLICY "$ENV{APPARMOR_POLICY}")

   configure_file(${CMAKE_CURRENT_SOURCE_DIR}/manifest.json.in
                  ${CMAKE_CURRENT_BINARY_DIR}/manifest.json @ONLY)
   configure_file(${CMAKE_CURRENT_SOURCE_DIR}/smsforwarder.apparmor.in
                  ${CMAKE_CURRENT_BINARY_DIR}/smsforwarder.apparmor @ONLY)

   qt5_add_resources(APP_RESOURCES resources.qrc)

   add_executable(smsforwarder src/main.cpp ${APP_SOURCES} ${APP_RESOURCES})
   target_compile_definitions(smsforwarder PRIVATE APP_VERSION="${APP_VERSION}")
   target_link_libraries(smsforwarder PRIVATE Qt5::Core Qt5::Gui Qt5::Network
                         Qt5::Qml Qt5::Quick OpenSSL::Crypto)

   install(TARGETS smsforwarder RUNTIME DESTINATION lib/${ARCH_TRIPLET}/bin)
   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/manifest.json
                 ${CMAKE_CURRENT_BINARY_DIR}/smsforwarder.apparmor
                 ${CMAKE_CURRENT_SOURCE_DIR}/smsforwarder.desktop DESTINATION .)
   install(DIRECTORY assets DESTINATION .)
   install(FILES LICENSE README.md CHANGELOG.md OPENSTORE-DESCRIPTION.txt SECURITY.md DIAGNOSTICS.md
           DESTINATION share/smsforwarder)

endif()

if(BUILD_REGRESSION_TESTS)
   enable_testing()
   find_package(Qt5 REQUIRED COMPONENTS Test)
   add_executable(test_persistence tests/test_persistence.cpp
      src/SettingsStore.cpp src/SettingsStore.h
      src/SmsForwarderBackend.cpp src/SmsForwarderBackend.h
      src/SmtpClient.cpp src/SmtpClient.h)
   target_compile_definitions(test_persistence PRIVATE APP_VERSION="${APP_VERSION}")
   target_link_libraries(test_persistence PRIVATE Qt5::Core Qt5::Network Qt5::Test OpenSSL::Crypto)
   add_test(NAME restart_persistence COMMAND test_persistence)
   add_executable(test_smtp tests/test_smtp.cpp
      src/SettingsStore.cpp src/SettingsStore.h
      src/SmsForwarderBackend.cpp src/SmsForwarderBackend.h
      src/SmtpClient.cpp src/SmtpClient.h)
   target_compile_definitions(test_smtp PRIVATE APP_VERSION="${APP_VERSION}")
   target_link_libraries(test_smtp PRIVATE Qt5::Core Qt5::Network Qt5::Test OpenSSL::Crypto)
   add_test(NAME local_tls_smtp COMMAND test_smtp)
endif()
