add_executable(test_imap_protocol test_imap_protocol.cpp ../src/ImapProtocol.cpp)
target_include_directories(test_imap_protocol PRIVATE ../src)
target_link_libraries(test_imap_protocol PRIVATE Qt5::Core)
add_test(NAME imap_protocol COMMAND test_imap_protocol)

add_library(securemail_test_backend STATIC
   ../src/SecureMailBackend.cpp
   ../src/SecureMailBackend.h
   ../src/SshTunnel.cpp
   ../src/SshTunnel.h
   ../src/SshNetwork.cpp
   ../src/SshNetwork.h
   ../src/SshRelay.cpp
   ../src/SshRelay.h
   ../src/ImapProtocol.cpp
   ../src/ImapProtocol.h
)
target_include_directories(securemail_test_backend PUBLIC ../src ${LIBSSH2_INCLUDE_DIR})
target_compile_definitions(securemail_test_backend PRIVATE APP_VERSION="${APP_VERSION}")
target_link_libraries(securemail_test_backend PUBLIC
   Qt5::Core Qt5::Gui Qt5::Network Qt5::Concurrent OpenSSL::Crypto Threads::Threads ${LIBSSH2_LIBRARY}
)

add_executable(test_email_aliases test_email_aliases.cpp)
target_link_libraries(test_email_aliases PRIVATE securemail_test_backend Qt5::Test)
add_test(NAME email_aliases COMMAND test_email_aliases)

add_executable(test_html_security test_html_security.cpp)
target_link_libraries(test_html_security PRIVATE securemail_test_backend Qt5::Test)
add_test(NAME html_security COMMAND test_html_security)

add_executable(test_protocol_integration test_protocol_integration.cpp)
target_link_libraries(test_protocol_integration PRIVATE securemail_test_backend Qt5::Test)
add_test(NAME protocol_integration COMMAND test_protocol_integration)

qt5_add_resources(QML_SECURITY_RESOURCES qml_security_resources.qrc)
add_executable(qml_security_tests qml_security_tests.cpp ${QML_SECURITY_RESOURCES})
target_include_directories(qml_security_tests PRIVATE ../src)
target_link_libraries(qml_security_tests PRIVATE Qt5::Core Qt5::Gui Qt5::Network Qt5::Qml Qt5::Quick)
add_test(NAME qml_security COMMAND qml_security_tests ${CMAKE_SOURCE_DIR})

set_tests_properties(html_security protocol_integration email_aliases qml_security PROPERTIES
   ENVIRONMENT "QT_QPA_PLATFORM=offscreen;QT_QUICK_BACKEND=software"
   TIMEOUT 90
)
set_tests_properties(imap_protocol PROPERTIES TIMEOUT 30)

add_executable(test_ssh_tunnel test_ssh_tunnel.cpp)
target_link_libraries(test_ssh_tunnel PRIVATE securemail_test_backend Qt5::Test)
add_test(NAME ssh_tunnel COMMAND test_ssh_tunnel)
set_tests_properties(ssh_tunnel PROPERTIES
   ENVIRONMENT "QT_QPA_PLATFORM=offscreen;QT_QUICK_BACKEND=software"
   TIMEOUT 30
)

add_executable(test_ssh_network test_ssh_network.cpp ../src/SshNetwork.cpp)
target_include_directories(test_ssh_network PRIVATE ../src)
target_link_libraries(test_ssh_network PRIVATE Threads::Threads)
add_test(NAME ssh_network COMMAND test_ssh_network)
set_tests_properties(ssh_network PROPERTIES TIMEOUT 30)

# Deliberately use the API double defined in this executable, not libssh2.so.
# The production relay and POSIX loopback sockets are real.
add_executable(test_ssh_relay test_ssh_relay.cpp ../src/SshRelay.cpp)
set_target_properties(test_ssh_relay PROPERTIES AUTOMOC OFF)
target_include_directories(test_ssh_relay PRIVATE ../src ${LIBSSH2_INCLUDE_DIR})
target_link_libraries(test_ssh_relay PRIVATE OpenSSL::Crypto Threads::Threads)
add_test(NAME ssh_relay COMMAND test_ssh_relay)
set_tests_properties(ssh_relay PROPERTIES TIMEOUT 45)
