cmake_minimum_required(VERSION 3.16)
project(securemail LANGUAGES CXX)

set(APP_VERSION "0.3.30")
set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_AUTOMOC ON)
set(CMAKE_POSITION_INDEPENDENT_CODE ON)

find_package(Qt5 REQUIRED COMPONENTS Core Gui Network Qml Quick)
find_package(OpenSSL REQUIRED)

if(NOT DEFINED ENV{ARCH_TRIPLET})
   message(FATAL_ERROR "ARCH_TRIPLET is not set. Build this project with Clickable.")
endif()

set(ARCH "$ENV{ARCH}")
set(ARCH_TRIPLET "$ENV{ARCH_TRIPLET}")
set(CLICK_FRAMEWORK "$ENV{CLICK_FRAMEWORK}")
set(APPARMOR_POLICY "$ENV{APPARMOR_POLICY}")

configure_file(
   ${CMAKE_CURRENT_SOURCE_DIR}/manifest.json.in
   ${CMAKE_CURRENT_BINARY_DIR}/manifest.json
   @ONLY
)

configure_file(
   ${CMAKE_CURRENT_SOURCE_DIR}/securemail.apparmor.in
   ${CMAKE_CURRENT_BINARY_DIR}/securemail.apparmor
   @ONLY
)

qt5_add_resources(APP_RESOURCES resources.qrc)

add_executable(
   securemail
   src/main.cpp
   src/BackupManager.cpp
   src/BackupManager.h
   src/SecureMailBackend.cpp
   src/SecureMailBackend.h
   ${APP_RESOURCES}
)

target_compile_definitions(securemail PRIVATE APP_VERSION="${APP_VERSION}")

target_link_libraries(
   securemail
   PRIVATE
   Qt5::Core
   Qt5::Gui
   Qt5::Network
   Qt5::Qml
   Qt5::Quick
   OpenSSL::Crypto
)

install(
   TARGETS securemail
   RUNTIME DESTINATION lib/${ARCH_TRIPLET}/bin
)

install(
   FILES
   ${CMAKE_CURRENT_BINARY_DIR}/manifest.json
   ${CMAKE_CURRENT_BINARY_DIR}/securemail.apparmor
   ${CMAKE_CURRENT_SOURCE_DIR}/securemail.desktop
   DESTINATION .
)

install(DIRECTORY assets DESTINATION .)

install(
   FILES
   ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE
   ${CMAKE_CURRENT_SOURCE_DIR}/README.md
   ${CMAKE_CURRENT_SOURCE_DIR}/OPENSTORE-DESCRIPTION.txt
   ${CMAKE_CURRENT_SOURCE_DIR}/CHANGELOG.md
   ${CMAKE_CURRENT_SOURCE_DIR}/SECURITY.md
   ${CMAKE_CURRENT_SOURCE_DIR}/securemail-config-template.json
   DESTINATION share/securemail
)
