cmake_minimum_required(VERSION 3.16)
project(picnicunofficial LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_AUTOMOC ON)
set(CMAKE_POSITION_INDEPENDENT_CODE ON)

find_package(Qt5 REQUIRED COMPONENTS Core Gui Network Qml Quick)

if(NOT DEFINED ENV{ARCH_TRIPLET})
   message(FATAL_ERROR "ARCH_TRIPLET is not set. Build this project with Clickable.")
endif()

set(ARCH "$ENV{ARCH}")
set(ARCH_TRIPLET "$ENV{ARCH_TRIPLET}")
set(CLICK_FRAMEWORK "$ENV{CLICK_FRAMEWORK}")
set(APPARMOR_POLICY "$ENV{APPARMOR_POLICY}")

configure_file(
   ${CMAKE_CURRENT_SOURCE_DIR}/manifest.json.in
   ${CMAKE_CURRENT_BINARY_DIR}/manifest.json
   @ONLY
)

configure_file(
   ${CMAKE_CURRENT_SOURCE_DIR}/picnicunofficial.apparmor.in
   ${CMAKE_CURRENT_BINARY_DIR}/picnicunofficial.apparmor
   @ONLY
)

qt5_add_resources(APP_RESOURCES resources.qrc)

add_executable(
   picnicunofficial
   src/main.cpp
   src/BackupManager.cpp
   src/BackupManager.h
   src/PicnicBackend.cpp
   src/PicnicBackend.h
   ${APP_RESOURCES}
)

target_link_libraries(
   picnicunofficial
   PRIVATE
   Qt5::Core
   Qt5::Gui
   Qt5::Network
   Qt5::Qml
   Qt5::Quick
)

install(
   TARGETS picnicunofficial
   RUNTIME DESTINATION lib/${ARCH_TRIPLET}/bin
)

install(
   FILES
   ${CMAKE_CURRENT_BINARY_DIR}/manifest.json
   ${CMAKE_CURRENT_BINARY_DIR}/picnicunofficial.apparmor
   ${CMAKE_CURRENT_SOURCE_DIR}/picnicunofficial.desktop
   DESTINATION .
)

install(
   DIRECTORY assets
   DESTINATION .
)

install(
   FILES
   ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE
   ${CMAKE_CURRENT_SOURCE_DIR}/THIRD-PARTY.md
   ${CMAKE_CURRENT_SOURCE_DIR}/third_party/MRVDH-picnic-api-LICENSE.txt
   DESTINATION share/picnicunofficial
)
