cmake_minimum_required(VERSION 3.16)
project(litellmchat LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_AUTOMOC ON)
set(CMAKE_POSITION_INDEPENDENT_CODE ON)

find_package(Qt5 REQUIRED COMPONENTS Core Gui Network Qml Quick)
include(CTest)

if(NOT DEFINED ENV{ARCH_TRIPLET})
   message(FATAL_ERROR "ARCH_TRIPLET is not set. Build this project with Clickable.")
endif()

set(ARCH "$ENV{ARCH}")
set(ARCH_TRIPLET "$ENV{ARCH_TRIPLET}")
set(CLICK_FRAMEWORK "$ENV{CLICK_FRAMEWORK}")
set(APPARMOR_POLICY "$ENV{APPARMOR_POLICY}")

configure_file(
   ${CMAKE_CURRENT_SOURCE_DIR}/manifest.json.in
   ${CMAKE_CURRENT_BINARY_DIR}/manifest.json
   @ONLY
)

configure_file(
   ${CMAKE_CURRENT_SOURCE_DIR}/litellmchat.apparmor.in
   ${CMAKE_CURRENT_BINARY_DIR}/litellmchat.apparmor
   @ONLY
)

qt5_add_resources(APP_RESOURCES resources.qrc)

add_executable(
   litellmchat
   src/main.cpp
   src/AppConstants.h
   src/SettingsStore.cpp
   src/SettingsStore.h
   src/BackupManager.cpp
   src/BackupManager.h
   src/LiteLLMBackend.cpp
   src/LiteLLMBackend.h
   ${APP_RESOURCES}
)

target_link_libraries(
   litellmchat
   PRIVATE
   Qt5::Core
   Qt5::Gui
   Qt5::Network
   Qt5::Qml
   Qt5::Quick
)

if(BUILD_TESTING)
   add_executable(
      settings_restart_test
      tests/test_settings_restart.cpp
      src/AppConstants.h
      src/SettingsStore.cpp
      src/SettingsStore.h
   )
   target_include_directories(settings_restart_test PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/src)
   target_link_libraries(settings_restart_test PRIVATE Qt5::Core)
   add_test(NAME settings_restart_persistence COMMAND settings_restart_test)

   add_executable(
      backup_manager_test
      tests/test_backup_manager.cpp
      src/AppConstants.h
      src/BackupManager.cpp
      src/BackupManager.h
   )
   target_include_directories(backup_manager_test PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/src)
   target_link_libraries(backup_manager_test PRIVATE Qt5::Core)
   add_test(NAME backup_manager_export COMMAND backup_manager_test)
endif()

install(
   TARGETS litellmchat
   RUNTIME DESTINATION lib/${ARCH_TRIPLET}/bin
)

install(
   FILES
   ${CMAKE_CURRENT_BINARY_DIR}/manifest.json
   ${CMAKE_CURRENT_BINARY_DIR}/litellmchat.apparmor
   ${CMAKE_CURRENT_SOURCE_DIR}/litellmchat.desktop
   DESTINATION .
)

install(
   DIRECTORY assets
   DESTINATION .
)

install(
   FILES
   ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE
   ${CMAKE_CURRENT_SOURCE_DIR}/README.md
   ${CMAKE_CURRENT_SOURCE_DIR}/THIRD-PARTY.md
   ${CMAKE_CURRENT_SOURCE_DIR}/OPENSTORE-DESCRIPTION.txt
   ${CMAKE_CURRENT_SOURCE_DIR}/CHANGELOG.md
   DESTINATION share/litellmchat
)
