cmake_minimum_required(VERSION 3.16)
project(lanexplorer LANGUAGES CXX)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_AUTOMOC ON)
set(CMAKE_POSITION_INDEPENDENT_CODE ON)

find_package(Qt5 REQUIRED COMPONENTS Core Gui Network Qml Quick)

if(NOT DEFINED ENV{ARCH_TRIPLET})
   message(FATAL_ERROR "ARCH_TRIPLET is not set. Build this project with Clickable.")
endif()

set(ARCH "$ENV{ARCH}")
set(ARCH_TRIPLET "$ENV{ARCH_TRIPLET}")
set(CLICK_FRAMEWORK "$ENV{CLICK_FRAMEWORK}")
set(APPARMOR_POLICY "$ENV{APPARMOR_POLICY}")

file(READ "${CMAKE_CURRENT_SOURCE_DIR}/manifest.json.in" MANIFEST_TEMPLATE)
string(REGEX MATCH "\"version\"[ \t]*:[ \t]*\"([^\"]+)\"" MANIFEST_VERSION_MATCH "${MANIFEST_TEMPLATE}")
if(NOT CMAKE_MATCH_1)
   message(FATAL_ERROR "Could not read version from manifest.json.in")
endif()
set(APP_VERSION "${CMAKE_MATCH_1}")

configure_file(
   ${CMAKE_CURRENT_SOURCE_DIR}/manifest.json.in
   ${CMAKE_CURRENT_BINARY_DIR}/manifest.json
   @ONLY
)

configure_file(
   ${CMAKE_CURRENT_SOURCE_DIR}/lanexplorer.apparmor.in
   ${CMAKE_CURRENT_BINARY_DIR}/lanexplorer.apparmor
   @ONLY
)

qt5_add_resources(APP_RESOURCES resources.qrc)

add_executable(
   lanexplorer
   src/main.cpp
   src/LanExplorerBackend.cpp
   src/LanExplorerBackend.h
   ${APP_RESOURCES}
)

target_compile_definitions(
   lanexplorer
   PRIVATE
   LANEXPLORER_VERSION=\"${APP_VERSION}\"
)

target_link_libraries(
   lanexplorer
   PRIVATE
   Qt5::Core
   Qt5::Gui
   Qt5::Network
   Qt5::Qml
   Qt5::Quick
)

install(
   TARGETS lanexplorer
   RUNTIME DESTINATION lib/${ARCH_TRIPLET}/bin
)

install(
   FILES
   ${CMAKE_CURRENT_BINARY_DIR}/manifest.json
   ${CMAKE_CURRENT_BINARY_DIR}/lanexplorer.apparmor
   ${CMAKE_CURRENT_SOURCE_DIR}/lanexplorer.desktop
   DESTINATION .
)

install(
   DIRECTORY assets
   DESTINATION .
)

install(
   FILES
   ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE
   ${CMAKE_CURRENT_SOURCE_DIR}/README.md
   ${CMAKE_CURRENT_SOURCE_DIR}/THIRD-PARTY.md
   DESTINATION share/lanexplorer
)
